Science Forums 2

[Janus]

Originally Posted by Pyrotex

Anybody that has POV files, may I have one or two? I am trying to learn POV-Ray, and it is damn hard without an example that works well.
Email them to me as attachements or post them here.

Thanks
Pyro

Try this one, it is fairly simple. I wouldn't render it at larger than 320x240, however, unless you are willing to wait for a while. I beefed up some of the settings for more realism, which slows it down a bit.

// ==== Standard POV-Ray Includes ====
#include "colors.inc" // Standard Color definitions
#include "textures.inc" // Standard Texture definitions
#include "functions.inc" // internal functions usable in user defined functions

// radiosity (global illumination) settings
global_settings {
radiosity {
pretrace_start 0.08 // start pretrace at this size
pretrace_end 0.04 // end pretrace at this size
count 350 // higher -> higher quality (1..1600) [35]
nearest_count 7 // higher -> higher quality (1..10) [5]
error_bound 1. // higher -> smoother, less accurate [1.8]
recursion_limit 3 // how much interreflections are calculated (1..5+) [3]
low_error_factor .5 // reduce error_bound during last pretrace step
gray_threshold 0.8 // increase for weakening colors (0..1) [0]
minimum_reuse 0.015 // reuse of old radiosity samples [0.015]
brightness 1 // brightness of radiosity effects (0..1) [1]

adc_bailout 0.01/2
normal on // take surface normals into account [off]
//media on // take media into account [off]
//save_file "file_name" // save radiosity data
//load_file "file_name" // load saved radiosity data
//always_sample off // turn sampling in final trace off [on]
//max_sample 1.0 // maximum brightness of samples
}
}
// set a color of the background (sky)
background { color rgb <0.3, 0.3, 0.3> }

// perspective (default) camera
camera {
location <0.0, 4.0, -5.0>
look_at <0.0, 0.0, 0.0>
right x*image_width/image_height
}

// An area light (creates soft shadows)
// WARNING: This special light can significantly slow down rendering times!
light_source {
0*x // light's position (translated below)
color rgb 1.0 // light's color
area_light
<8, 0, 0> <0, 0, 8> // lights spread out across this distance (x * z)
4, 4 // total number of lights in grid (4x*4z = 16 lights)
adaptive 0 // 0,1,2,3...
jitter // adds random softening of light
circular // make the shape of the light circular
orient // orient light
translate <40, 80, -40> // <x y z> position of light
}


#declare dimple1 = union
{

#declare Count = 0;
#while (Count < 40)
sphere{<0,0,0>, .1 translate x*1.06 rotate y*Count*9}
#declare Count=Count+1;
#end
}

#declare dimple2 = object{dimple1 rotate y*4.5}

#declare dimple3 = union
{
#declare count2 = 0;
#while (count2<10)
object {dimple1 rotate z*18*count2}
object {dimple2 rotate z*9 rotate z*18*count2}
#declare count2=count2+1;
#end
}

difference
{

sphere
{<0,0,0>,1}
object{dimple3}
pigment{color White}
finish {specular .5 roughness .007 ambient 0}
rotate y*90

}



plane
{ y, -1.0
texture
{
DMFWood6
translate
x*10
rotate y*30
}
finish{ambient 0}
normal
{
wood .075
turbulence 0.04
octaves 3
scale <0.05, .05, 1>
translate x*10
rotate y*30
}
}

plane
{ z, 3.0
texture
{
pigment{color Wheat}
finish{specular .15 roughness .03 ambient 0}
normal{bumps .025 scale.15}
}
}